En el taller de fórmulas de Crystal Report se deben crear las funciones personalizadas:

Primero crearemos la función ConvertiraDecimal que nos servirá para convertir valores hexadecimales a valores, siendo el código fuente de la función:

Function ConvertirADecimal (HexToConvert as string)
    If Len(HexToConvert) > 0 Then
        Dim hexValue As String
        hexValue = Right(HexToConvert, Len(HexToConvert)-2)

        Dim hexValueLen As Number
        hexValueLen = Len(hexValue)

        Dim i As Number
        Dim decimalResult As Number
        decimalResult = 0

        For i = 0 To hexValueLen
            Select Case Mid(hexValue, i+1, 1)     
             Case "a"
              decimalResult = decimalResult+10*(16 ^ (len(hexValue)-(i+1)))
             Case "b" 
              decimalResult = decimalResult+11*(16 ^ (len(hexValue)-(i+1)))
             Case "c" 
              decimalResult = decimalResult+12*(16 ^ (len(hexValue)-(i+1)))
             Case "d" 
              decimalResult = decimalResult+13*(16 ^ (len(hexValue)-(i+1)))
             Case "e" 
              decimalResult = decimalResult+14*(16 ^ (len(hexValue)-(i+1)))
             Case "f"  
              decimalResult = decimalResult+15*(16 ^ (len(hexValue)-(i+1)))
             Case Else 
              decimalResult = decimalResult+Val(Mid (hexValue,i+1,1))*(16 ^ (len(hexValue)-(i+1)))
            End Select
       Next i  
    End If 

    ConvertirADecimal = decimalResult
End Function

Después crearemos la función ColorFromHex para convertir el valor hexadecimal en el color, estando compuesto el hexadecimal por cuatro pares de valores equivalentes a los valores de transparencia, rojo, verde y azul. El código de la siguiente función se encargará de generar el color utilizando los valores RGB y desechando el valor de transparencia:

Function ColorFromHex (HexColor as string)
     
 Dim part1 as string
 Dim part2 as string
 Dim part3 as string

 if len(HexColor)>6 then
    HexColor=Right(HexColor,6)
 end if
 
 part1="0x" & Mid(HexColor,1,2)
 part2="0x" & Mid(HexColor,3,2)
 part3="0x" & Right(HexColor,2)
 
 ColorFromHex =Color(ConvertirADecimal(Part1),ConvertirADecimal(Part2),ConvertirADecimal(Part3))

End Function

Ejemplo: Convertir a decimal  FF9ACD32

Los dos primeros dígitos se desechan y se convierte a decimal los valores 9A (rojo), CD (verde) y 32 (azul) mostrando como resultado el color:

A continuación se muestra la lista de etiquetas HTML compatibles:

• html
• body
• div (provoca un salto de párrafo)
• tr (sólo provoca un salto de párrafo; no conserva la estructura de columnas de una tabla)
• span
• font
• p (provoca un salto de párrafo)
• br (provoca un salto de párrafo)
• h1 (provoca un salto de párrafo, hace que la fuente esté en negrita y el doble de tamaño predeterminado)
• h2 (provoca un salto de párrafo, hace que la fuente esté en negrita y 1,5 veces el tamaño predeterminado)
• h3 (provoca un salto de párrafo, pone la fuente en negrita y el tamaño predeterminado de 9/8)
• h4 (provoca un salto de párrafo, hace que la fuente esté en negrita)
• h5 (provoca un salto de párrafo, pone la fuente en negrita y el tamaño predeterminado de 5/6)
• h6 (provoca un salto de párrafo, pone la fuente en negrita y el tamaño predeterminado de 5/8)
• center (texto alineado al centro)
• big (provoca un salto de párrafo, pone la fuente en negrita y el tamaño predeterminado de 5/8)
• small (disminuye el tamaño de fuente en 2 puntos si es de 8 puntos o más)
• b (negrita)
• i (cursiva)
• s (tachado)
• strike (tachado)
• u (subrayado)

Los atributos HTML admitidos son:

• align
• face
• size
• color
• font-family
• font-size
• font-style
• font-weight

Fuentes:

SAP Knowledge Base Article

Mediante Crystal Report es posible generar códigos de barras Code 39, aunque para ellos es necesario realizar los siguientes pasos:

1. Descargar e instalar una fuente de código de barras Code 39 en servidor y los equipos desde donde se vayan a imprimir los códigos de barras.

2. En el taller de fórmulas de Crystal Report, se debe crear una fórmula (por ejemplo CodigoBarras), donde añadiremos un asterisco (*) al inicio y fin del campo o cadena que contenga el código de barras, así la fórmula devolverá una expresión que generará el código de barras:  

3. Por último, diseñaremos el informe insertando la fórmula en la posición que deseemos y estableciéndole la fuente de código de barras Code 39.  

1. Descargar e instalar la fuente ean13.ttf en servidor y los equipos desde donde se vayan a imprimir los códigos de barras.

2. En el taller de fórmulas de Crystal Report se debe crear una función personalizada (por ejemplo Generar_EAN13):  

3. En la función deberemos copiar el código de las funciones de Crystal Report.

4. Posteriormente crearemos una fórmula (por ejemplo CodigoBarras) que haga referencia a la función creada, donde le pasaremos como parámetro un campo o una cadena que contenga el código EAN13 y dicha fórmula devolverá una expresión que generará el código de barras:  

5. Por último, diseñaremos el informe insertando la fórmula en la posición que deseemos y estableciéndole la fuente Code EAN13.  

Funciones de Crystal Report

Function Generar_EAN13(Codigo As String) As String

    ' Esta función permite generar el código de barras para mostrarlo con la fuente EAN13.TTF
    ' - Parametros : código de 12 o 13 dígitos
    ' - Retorno: retorna una cadena que permite representar generar el código de barras con la fuente EAN13.TTF
    '            retorna una cadena vacía si no se puede representar el código de barras

    dim i,  first, checksum as number
    dim code, code13 as string
    dim tableA as boolean

    ' Evaluar los dígitos del código
    If Len(Codigo) = 12 then
        code = Codigo
    ElseIf Len(Codigo) = 13 then
        code = Left(Codigo,12)
    Else
        code = ""
    end If
  
    ' Verificar los dígitos del código
    For i = 1 To LEN(code)
        If Asc(Mid(code, i, 1)) < 48 Or Asc(Mid(code, i, 1)) > 57 Then
            code = ""
            Exit For
        End If
    Next

    ' Chequea los 12 dígitos y cálcula el digito de control
    If Len(code) = 12 Then
        For i = 12 To 1 Step -2
            checksum = checksum + Val(Mid(code, i, 1))
        Next
        checksum = checksum * 3
        For i = 11 To 1 Step -2
            checksum = checksum + Val(Mid(code, i, 1))
        Next
        code = code & ToText((10 - checksum Mod 10) Mod 10,0)

        ' Si el código inicial tenía 13 dígitos comprueba si el nuevo código generado
        ' es igual y en caso contrario no se generar ningún código
        If Len(Codigo)=13 and Codigo<>code then
            code = ""
        end If
    End If

    ' Chequea los 13 dígitos
    If Len(code) = 13 Then
        ' Los primeros 2 dígitos que suelen corresponder al código del país
        code13 = Left(code, 1) & Chr(65 + Val(Mid(code, 2, 1)))
        first = Val(Left(code, 1))

        ' Generar los códigos del primer bloque de dígitos
        For i = 3 To 7
            tableA = False
            Select Case i
                Case 3
                    Select Case first
                        Case 0 To 3
                            tableA = True
                    End Select
                Case 4
                    Select Case first
                        Case 0, 4, 7, 8
                            tableA = True
                    End Select
                Case 5
                    Select Case first
                        Case 0, 1, 4, 5, 9                 
                            tableA = True
                    End Select
                Case 6
                    Select Case first
                        Case 0, 2, 5, 6, 7
                            tableA = True
                    End Select
                Case 7
                    Select Case first
                        Case 0, 3, 6, 8, 9
                            tableA = True
                    End Select
            End Select
            If tableA Then
                code13 = code13 & Chr(65 + Val(Mid(code, i, 1)))
            Else
                code13 = code13 & Chr(75 + Val(Mid(code, i, 1)))
            End If
        Next

        ' Añadir el separador de los bloques
        code13 = code13 & "*"

        ' Generar los códigos del segundo bloque de dígitos
        For i = 8 To 13
            code13 = code13 & Chr(97 + Val(Mid(code, i, 1)))
        Next

        ' Añadir la marca final
        code13 = code13 & "+"
    End If

    Generar_EAN13=code13

End Function

Nota: si se utiliza otro nombre de función entonces es necesario cambiarlo en todo el código fuente.

1. Descargar e instalar la fuente ean128.ttf en servidor y los equipos desde donde se vayan a imprimir los códigos de barras.

2. En el taller de fórmulas de Crystal Report se deben crear dos funciones personalizadas (por ejemplo Generar_EAN128 y TestNum):

3. En la función deberemos copiar el código del apartado funciones de Crystal Report.

4. Posteriormente crearemos una fórmula (por ejemplo Code128) que haga referencia a la función creada, donde le pasaremos como parámetro un campo, fórmula o una cadena que contenga el código EAN128 y dicha fórmula devolverá una expresión que generará el código de barras:

5. Por último, diseñaremos el informe insertando la fórmula en la posición que deseemos y estableciéndole la fuente Code128, además si deseamos que figure el texto del código de barras entonces debemos insertar el código de barras en la posición deseada.

Funciones de Crystal Report

Function TestNum (Codigo as string, i as number, mini as number) as Number
   'Si los caracteres de la variable mini desde la variable i son numericos entonces se devuelve 0
   mini = mini - 1
   If i + mini <= Len(Codigo) Then
      Do While mini >= 0
         If Asc(Mid(Codigo, i + mini, 1)) < 48 Or Asc(Mid(Codigo, i + mini, 1)) > 57 Then Exit Do
         mini = mini - 1
      Loop
   End If
   TestNum = mini
End Function


Function Generar_EAN128(Codigo as String) As String
 ' V 2.0.0 
 ' Esta función permite generar el código de barras para mostrarlo con la fuente CODE128.TTF
 ' - Parametros : cadenas del código
 ' - Retorno: retorna una cadena que permite representar generar el código de barras con la fuente CODE128.TTF
 '            retorna una cadena vacía si no se puede representar el código de barras
 dim i, checksum, mini, dummy as number
 dim code128 as string
 dim tableB As Boolean
 code128=""     
 If Len(Codigo) > 0 Then
     ' Verificar si los caracteres son válidos
     For i = 1 To Len(Codigo)
         Select Case Asc(Mid(Codigo, i, 1))
             Case 32 To 126, 203
             Case Else
                 Codigo=""
                 Exit For
         End Select
     Next
 End If
 If Len(Codigo) > 0 Then
     'Calcular de la cadena de código optimizando el uso de las tablas B y C
     tableB=true
     i = 1
     ' Iniciar el indice de la cadena
     Do While i <= Len(Codigo)
         If tableB Then
           'Ver si interesa cambiar a la tabla C si para 4 dígitos de inicio o final sino 6 dígitos
           mini = IIf(i = 1 Or i + 3 = Len(Codigo), 4, 6)
           mini = TestNum (Codigo, i, mini)
           If mini < 0 Then 'Cambiando a la tabla C
             If i = 1 Then 'Iniciando con la tabla C
               code128 = Chr(210)
             Else 'Cambiar a la tabla C
               code128 = code128 & Chr(204)
             End If
             tableB = False
           Else
             If i = 1 Then code128 = Chr(209) 'Iniciando con la tabla B
           End If
         End If
         If Not tableB Then
             'Si estabamos en la tabla C se intentan procesar 2 dígitos
             mini = 2
             mini = TestNum (Codigo, i, mini)
             If mini < 0 Then 'Procesar 2 dígitos
                 dummy = Val(Mid(Codigo, i, 2)) 
                 dummy = IIf(dummy < 95, dummy + 32, dummy + 105)
                 code128 = code128 & Chr(dummy)
                 i = i + 2
             Else 'Si no tiene 2 dígitos se cambia a la tabla B
                 code128 = code128 & Chr(205)
                 tableB = True
             End If
         End If
         If tableB Then
           'Procesar 1 dígito con la tabla B
           code128 = code128 & Mid(Codigo, i, 1)
           i = i + 1
         End If 
    Loop

     'Calcular el checksum
     For i = 1 To Len(code128)
         dummy = Asc(Mid(code128, i, 1))
         dummy = IIf(dummy < 127, dummy - 32, dummy - 105)
         If i = 1 Then checksum = dummy
         checksum = (checksum + (i - 1) * dummy) Mod 103
     Next

     'Calculando el código ASCII de checksum
     checksum = IIf(checksum < 95, checksum + 32, checksum + 105)

     'Añadir el checksum y parar
     code128 = code128 & Chr(checksum) & Chr(211) 
End If 

Generar_EAN128=code128
End Function

Nota: si se utilizan otros nombres de función entonces es necesario cambiarlo en todo el código fuente.

1. En el taller de fórmulas de Crystal Report se deben crear dos funciones personalizadas (NumeroALetras y NumerosALetras):

3. Posteriormente crearemos una fórmula (por ejemplo ImporteALetras) que haga referencia a la función creada, donde le pasaremos como parámetro un campo, fórmula o un número que contenga el importe y dicha fórmula devolverá una expresión con el importe en letras. En el siguiente ejemplo se convierte un importe monetario en letras incluyendo la moneda. 

' número a convertir
dim numero as number
numero = 0

formula = ""
if numero < 0 then
    numero = abs(numero)
    formula = "MENOS "
end if

' parte entera
dim entero as number
entero = truncate(numero)
formula = formula & NumerosALetras(entero)
formula = formula & " EUROS"

' parte decimal
dim decimales as number
decimales = Round((numero - entero) * 100, 2)

if decimales > 0 then
    formula = formula & " CON " &  NumerosALetras(decimales)
    formula = formula & " CENTIMOS"
end if

4. Por último, diseñaremos el informe insertando la fórmula en la posición que deseemos.  

Funciones personalizadas de Crystal Report

Function NumeroALetras(numero As number) As String

	Dim text As String
	Dim value As number
	value = Truncate(numero)

	If value = 0 Then
		text = "CERO"
	ElseIf value = 1 Then
		text = "UN"
	ElseIf value = 2 Then
		text = "DOS"
	ElseIf value = 3 Then
		text = "TRES"
	ElseIf value = 4 Then
		text = "CUATRO"
	ElseIf value = 5 Then
		text = "CINCO"
	ElseIf value = 6 Then
		text = "SEIS"
	ElseIf value = 7 Then
		text = "SIETE"
	ElseIf value = 8 Then
		text = "OCHO"
	ElseIf value = 9 Then
		text = "NUEVE"
	ElseIf value = 10 Then
		text = "DIEZ"
	ElseIf value = 11 Then
		text = "ONCE"
	ElseIf value = 12 Then
		text = "DOCE"
	ElseIf value = 13 Then
		text = "TRECE"
	ElseIf value = 14 Then
		text = "CATORCE"
	ElseIf value = 15 Then
		text = "QUINCE"
	ElseIf value < 20 Then
		text = "DIECI" & "#" & ToText(value - 10,0) & "#"
	ElseIf value = 20 Then
		text = "VEINTE"
	ElseIf value < 30 Then
		text = "VEINTI" & "#" & ToText(value - 20,0) & "#"
	ElseIf value = 30 Then
		text = "TREINTA"
	ElseIf value < 40 Then
		text = "TREINTA Y " & "#" & ToText(value - 30,0) & "#"
	ElseIf value = 40 Then
		text = "CUARENTA"
	ElseIf value < 50 Then
		text = "CUARENTA Y " & "#" & ToText(value - 40,0) & "#"
	ElseIf value = 50 Then
		text = "CINCUENTA"
	ElseIf value < 60 Then
		text = "CINCUENTA Y " & "#" & ToText(value - 50,0) & "#"
	ElseIf value = 60 Then
		text = "SESENTA"
	ElseIf value < 70 Then
		text = "SESENTA Y " & "#" & ToText(value - 60,0) & "#"
	ElseIf value = 70 Then
		text = "SETENTA"
	ElseIf value < 80 Then
		text = "SETENTA Y " & "#" & ToText(value - 70,0) & "#"
	ElseIf value = 80 Then
		text = "OCHENTA"
	ElseIf value < 90 Then
		text = "OCHENTA Y " & "#" & ToText(value - 80,0) & "#"
	ElseIf value = 90 Then
		text = "NOVENTA"
	ElseIf value < 100 Then
		text = "NOVENTA Y " & "#" & ToText(value - 90,0) & "#"
	ElseIf value = 100 Then
		text = "CIEN"
	ElseIf value < 200 Then
		text = "CIENTO " & "#" & ToText(value - 100,0) & "#" 
	ElseIf value = 200 Then
		text = "DOSCIENTOS"
	ElseIf value = 300 Then
		text = "TRESCIENTOS"
	ElseIf value = 400 Then
		text = "CUATROCIENTOS"
	ElseIf value = 500 Then
		text = "QUINIENTOS"
	ElseIf value = 600 Then
		text = "SEISCIENTOS"
	ElseIf value = 700 Then
		text = "SETECIENTOS"
	ElseIf value = 800 Then
		text = "OCHOCIENTOS"
	ElseIf value = 900 Then
		text = "NOVECIENTOS"
	ElseIf value < 1000 Then
		text =  "#" & ToText(Truncate(value / 100) * 100,0) & "# #" & ToText(value Mod 100,0) & "#" 
	ElseIf value = 1000 Then
		text = "MIL"
	ElseIf value < 2000 Then
		text = "MIL #" & ToText(value Mod 1000,0) & "#" 
	ElseIf value < 1000000 Then
		text = "#" & ToText(Truncate(value / 1000),0) & "# MIL"
		If (value Mod 1000) > 0 Then text = text & " #" & ToText(value Mod 1000,0) & "#" 
	ElseIf value = 1000000 Then
		text = "UN MILLÓN"
	ElseIf value < 2000000 Then
		text = "UN MILLÓN #" & ToText(value Mod 1000000,0) & "#" 
	Else
		text = "#" & ToText(Truncate(value / 1000000),0) & "# MILLONES"
		If (value Mod 1000000) > 0 Then text = text & " #" & ToText(value Mod 1000000,0) & "#" 
	End If

	NumeroALetras = text
End Function

Function NumerosALetras (numero As number) As String
      
    Dim texto As String
    Dim numTexto As String
    Dim numLetras As String
    Dim posInicial As Number
    Dim posFinal As Number

    texto = "#" & ToText(Truncate(numero),0) & "#"

    Do While InStr(texto, "#") > 0
        posInicial = InStr(texto, "#")+1
        posFinal = InStr(posInicial, texto, "#")
    
        If posFinal > 0 Then
            numTexto = Mid(texto, posInicial, posFinal - posInicial)
            numLetras = NumeroALetras(ToNumber(numTexto))
            texto = Replace(texto, "#" & numTexto & "#", numLetras)
        Else
            Exit Do
        End If
    Loop

    NumerosALetras = texto

End Function

Nota: si se utiliza otro nombre de función entonces es necesario cambiarlo en todo el código fuente.

A continuación se detallan los pasos para la creación de parámetros permitiendo su compatibilidad con Aliquo:

1. Establecer el nombre y tipo de valor que contendrá el parámetro. La opción de lista de valores se dejará como Estático.

2. Si se desea se puede hacer una lista de valores y descripciones (por temas de compatibilidad la descripción deberá indicarse en la columna de valor con el formato valor;descripción)  

• Sólo valores

  

• Valores y descripción

  

3. Se deben indicar las diferentes opciones de valor, aunque por compatibilidad sólo están permitidas las siguientes opciones: 

• Mostrar en panel (visor): mediante esta opción se indica si se puede editar u ocultar el parámetro en el panel de parámetros.

• Texto de petición: permite indicar el texto que se desea que aparezca a la hora de solicitar el valor.

• Petición con sólo descripción: cuando se utilizan listas de valores se pueden indicar si la lista contendrá el valor y la descripción o sólo la descripción.

• Petición opcional: indica si el valor del parámetro puede estar  vacío, por supuesto en el caso de tipos numéricos será 0 y en fecha será la mínima permitida.

• Permitir valores personalizados: cuando se utilizan listas de valores permite indicar si se puede establecer valores distintos a los establecidos en dicha lista.

• Longitud mínima y máxima (exclusivo del tipo cadena): permite indicar el tamaño mínimo y máximo de caracteres que debe tener el valor.

• Iniciar y finalizar (exclusivo para el tipo fecha y hora): establece la fecha/hora de inicio y fin entre la que debe encontrarse el valor del parámetro.

• Valor mínimo y máximo (exclusivo del tipo número y moneda): indica el valor mínimo y máximo permitido para el valor de dicho parámetro.

A continuación se detallan los pasos para realizar un documento con varios esquemas combinados, para ello vamos a realizar un ejemplo que muestre los contactos de los clientes:
 

1. Generar el esquema de la tabla principal mediante Configuración/Esquema de tablas, para este ejemplo la tabla de Clientes.
2. En la pantalla de generar esquema seleccionaremos los campos que deseemos mostrar en el documento (por ejemplo Clientes.Código y Clientes.Nombre) y guardaremos el esquema en una carpeta con el nombre que deseemos (por ejemplo Esquema_Contactos.xsd).

   

3. Mediante Configuración/Esquemas de tablas volveremos a generar otro esquema para la tabla vinculada, en este caso seleccionaremos la tabla Clientes_Contactos.
4. En la pantalla de generar esquema seleccionaremos los campos que deseemos mostrar (por ejemplo Clientes_Contactos.Nombre y Clientes.Contactos.Teléfono_móvil) aunque lo más importante es elegir el campo que relaciona esta tabla con la tabla principal, en este caso Clientes.Contactos.CodCliente. 

   

5. Una vez elegidos los campos, guardaremos el esquema seleccionando el mismo archivo generado anteriormente y como ya existe el archivo nos preguntará si deseamos combinar el esquema, en este caso indicaremos que Sí deseamos combinar, obteniendo de esta forma un único esquema de datos de las tablas de Clientes y Clientes_Contactos. 

   

6. Posteriormente en Crystal Report seleccionaremos el esquema guardado, permitiéndonos seleccionar las tablas que se incluyen en dicho esquema. 

7. En la siguiente pantalla de Crystal Report deberemos crear los vínculos de dichas tablas par que funcione el documento. En este caso se ha creado el vínculo del campo Clientes.Código de la tabla Clientes con el campo Clientes_Contactos.CodCliente de la tabla Clientes_Contactos. 

   

   Si se desea que salgan todos los clientes aunque no tengan contactos, entonces se debe pulsar con el botón derecho del ratón sobre el vínculo y seleccionar opciones de vínculo.  

   

   Después en la pantalla de Opciones de vínculo se debe seleccionar la opción de Combinación externa izquierda.  

   

8. Por último, sólo nos queda diseñar el documento y guardarlo en la carpeta correspondiente a la tabla principal (por ejemplo… Aliquo\Server\Empresas\Emp0001\Documentos\Tablas\Clientes) 

   

9. Una vez finalizado todo el proceso, dispondremos en la tabla correspondiente del documento, por lo que sólo tendremos que seleccionar los clientes y elegir dicho documento de impresión.

1. En el taller de fórmulas de Crystal Report se debe crear una función personalizada (por ejemplo NumDecimales):  

2. En la función deberemos copiar el código de las funciones de Crystal Report.

3. Después crearemos una fórmula (por ejemplo: una fórmula para formatear el campo tiempo según el número de decimales) que haga la referencia a la función creada, donde le pasaremos como parámetro el campo que contiene el número sobre el necesitamos conocer la cantidad de decimales.

Funciones de Crystal Report

Function NumDecimales(Numero as number, optional MaxDecimales as number=2) as number
    NumDecimales=MaxDecimales
    
    dim Pos as number
    for Pos = 0 to MaxDecimales
        if Numero=Fix(Numero,Pos) then
            NumDecimales=Pos
            Exit for
        end if
    next
End Function

Nota: si se utiliza otro nombre de función entonces es necesario cambiarlo en todo el código fuente.